*** Settings ***
Documentation  1. Формування посилань на модуль аукціону
    ...  Одна подана заява на участь протягом tenderPeriod (під час Голландського етапу)
    ...  https://confluence-sale.prozorro.org/pages/viewpage.action?pageId=63276306#id-ТестуванняМАDutch-CBD3-DU-MA-UC-01-03
Default Tags  module_1
Resource  ../fixtures/Resources/auction_conditions.robot
Test Setup  Check For Pass Before
Suite Setup  Create Session  api_procedures  %{PROCEDURE_URL}  verify=True
Suite Teardown  Run Keywords  Delete All Sessions  Close All Browsers 


*** Variables ***
${AUCTION_NAME}  subsoil-dutch-initial-auction


*** Test Cases ***
Перевірити формування в ЦБД публічного посилання для спостерігання за модулем аукціону.

    ${ACTION_START_TIME}=  Get Time  format=timestamp  time_=UTC +5m

    Import Variables  ../fixtures/${AUCTION_NAME}.py  init_auction
    Import Variables  ../fixtures/subsoil-dutch-fast-bid.py  init_bid
    
    Set To Dictionary  ${init_auction["auctionPeriod"]}  startDate  ${ACTION_START_TIME}
    ${RESP} =  POST On Session  api_procedures  /api/procedures  json=${init_auction}  headers=${DEFAULT_HEADERS}  expected_status=201
    ${ID} =  Get From Dictionary  ${resp.json()}  id
    Set Suite Variable  ${ID}  ${ID}
    Sleep  5m 30s  Waiting for active_auction
    ${RESP} =  Get Request and return resp By  ${ID}  ${WATCHER}
    Status Should Be  200  ${RESP}
    ${STATUS} =  Get From Dictionary  ${resp.json()}  status
    Should Be Equal  active_auction  ${STATUS}
    ${AUCTION_URL} =  Get From Dictionary  ${resp.json()}  auctionUrl
    Set Suite Variable  \${AUCTION_URL} 
    ${AUCTION_ID} =  Get From Dictionary  ${resp.json()}  auctionId
    Set Suite Variable  \${AUCTION_ID}
Подати одну заяву на участь протягом tenderPeriod під час Голландського раунду.

    Open Browser Maximized   ${AUCTION_URL}
    Wait Until Page Contains Element  //li[@class='stages-item is-disabled']
    ${RESP} =  POST On Session  api_procedures  /api/procedures/${ID}/bids  json=${init_bid}  headers=${DEFAULT_HEADERS}  expected_status=201
    Status Should Be  201  ${RESP}
    ${BID_ID} =  Get From Dictionary  ${resp.json()}  id
    Set Suite Variable  ${BID_ID}  ${BID_ID}
    ${BID_ACC_TOKEN} =  Get From Dictionary  ${resp.json()}  acc_token
    Set Suite Variable  ${BID_ACC_TOKEN}  ${BID_ACC_TOKEN}
    ${RESP} =  PATCH On Session  api_procedures  /api/procedures/${ID}/bids/${BID_ID}/status  data={"status":"active"}  headers=${DEFAULT_HEADERS}  params=acc_token=${BID_ACC_TOKEN}
    Status Should Be  200  ${RESP}

Перевірити формування в ЦБД приватного посилання для участі в модулі аукціону.

    Open Browser Maximized   ${AUCTION_URL}  ${WATCHER}
    Wait Until Page Contains Element  //a[@class='header-id']
    Element Should Contain  //a[@class='header-id']  ${AUCTION_ID} 
    ${BIDDER_URL} =  Get Request and return participationUrl By  ${ID}  ${BID_ACC_TOKEN}
    Open Browser Maximized  ${BIDDER_URL}
    Allow Terms  ${BIDDER_URL}
    Page Should Contain Element  //div[@class='b-user-id-item' and contains(.,'ID')]